home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Software Vault: The Gold Collection
/
Software Vault - The Gold Collection (American Databankers) (1993).ISO
/
cdr11
/
pcv05n08.zip
/
CL.BAT
< prev
next >
Wrap
DOS Batch File
|
1993-06-12
|
2KB
|
71 lines
@ECHO OFF
REM NAME: CL.BAT
REM PURPOSE: Store Command Lines
SET USE=
IF (%1)==(ABC123XYZ) GOTO SHOWTHEM
IF (%1)==(/?) GOTO HELP
IF (%1)==() GOTO MISSING
IF (%1)==(D) GOTO DISPLAY
IF (%1)==(d) GOTO DISPLAY
IF NOT EXIST C:\CL\*.* MD C:\CL
FOR %%J IN (0 1 2 3 4 5 6 7 8 9) DO IF (%1)==(%%J) GOTO RUN
FOR %%J IN (9 8 7 6 5 4 3 2 1 0) DO IF NOT EXIST C:\CL\%%J.BAT SET USE=%%J
IF NOT (%USE%)==() GOTO USE
GOTO ALLUSED
:RUN
CALL C:\CL\%1.BAT
GOTO END
:USE
SHIFT
ECHO @ECHO OFF > C:\CL\%USE%.BAT
ECHO %0 %1 %2 %3 %4 %5 %6 %6 %7 %8 %9 >> C:\CL\%USE%.BAT
C:\CL\%USE%.BAT
GOTO END
:ALLUSED
DEL C:\CL\0.BAT
REN C:\CL\1.BAT 0.BAT
REN C:\CL\2.BAT 1.BAT
REN C:\CL\3.BAT 2.BAT
REN C:\CL\4.BAT 3.BAT
REN C:\CL\5.BAT 4.BAT
REN C:\CL\6.BAT 5.BAT
REN C:\CL\7.BAT 6.BAT
REN C:\CL\8.BAT 7.BAT
REN C:\CL\9.BAT 8.BAT
SET USE=9
GOTO USE
:DISPLAY
FOR %%J IN (0 1 2 3 4 5 6 7 8 9) DO CALL CL ABC123XYZ %%J
GOTO END
:SHOWTHEM
IF NOT EXIST C:\CL\%2.BAT GOTO END
ECHO --%2--
TYPE C:\CL\%2.BAT | FIND /V "@ECHO OFF"
ECHO.
GOTO END
:MISSING
ECHO CL.BAT requires the following parameters:
ECHO.
ECHO To store a command line, enter CL followed by commands
ECHO To display stored command lines, enter CL D
ECHO To reuse a command line, enter CL followed by its number
ECHO.
GOTO DISPLAY
:HELP
ECHO CL.BAT stores command lines in batch files in the
ECHO C:\CL directory, to replay later
ECHO.
ECHO To store a command line, enter CL followed by commands
ECHO.
GOTO END
:END